/* Finds the fastest Amiganet server and connects to it.
** NOTE: Change the ping command below if you are not using Miami! */

ping='miami:miamiping -c 4'
/* ping='ping -c 4' */  /* this line could work if you don't have Miami */

options results
serv.1='whiterose.us.amiganet.org'
serv.2='thule.no.amiganet.org'
serv.3='kth.se.amiganet.org'
serv.4='fastlane.au.amiganet.org'
serv.5='linux.us.amiganet.org'
serv.6='stayfree.uk.amiganet.org'

'GetServerName'
current=result
'Channels'
channels=translate(strip(result),',',' ')

file='t:ping.result'
min=99999
i=1

do while serv.i~='SERV.'||i
    address command ping '>'file serv.i
    call open(1,file,'r')
    r=''
    do until pos('round-trip',r)>0 | eof(1)
        r=readln(1)
        end
    call close(1)
    if pos('round-trip',r)>0 then do
        r=substr(r,pos('=',r)+1)
        r=translate(r,' ','/')
        avg=word(r,2)
        if avg<min then do
            min=avg
            best=serv.i
            end
        'echo p=»FastAnet«' trunc(avg,0) 'ms to' serv.i
        end
    i=i+1
    end

if upper(current)=upper(best) then do
    'echo p=»FastAnet« You are already connected to the fastest server!'
    exit
    end

'echo p=»FastAnet« Connecting to' best
'say /server' best
'say /join' channels
exit